; Универсальный скрипт для подключения к БелПак.
; Поддерживает протоколы SLIP и PPP 
; со статической и динамической IP-адресацией.
; Имя и пароль пользователя берутся из окна дозвонки

; Main entry point to script
;
proc main

   ; В этой секции описаны используемые в скрипте константы
   ; при желании возможно изменение их значений

   ; общее число попыток входа:

   integer nTries = 3
   
   ; приглашение для входа:

   string szLogin = "Login:"

   ; время ожидания приглашения для входа, сек:

   integer nLoginTimeout = 3

   ; приглашение для пароля:
   
   string szPW = "password:"
   
   ; время ожидания приглашения для пароля, сек:

   integer nPWTimeout = 3
   
   ; -----------------------------------------------------

   ; Собственно процедура входа:

   ; Ожидание приглашения и ввод входного имени:

   while 0 < nTries do
      waitfor szLogin then DoLogin 
        until nLoginTimeout

TryAgain:
      transmit "^M"        
      nTries = nTries - 1

   endwhile

   goto BailOut

DoLogin:
   ; Enter user ID

   transmit $USERID, raw
   transmit "^M"

   ; Ожидание приглашения и ввод пароля:

   waitfor szPW until nPWTimeout
   if FALSE == $SUCCESS then
      goto TryAgain
   endif

   transmit $PASSWORD, raw
   transmit "^M"

   ; Если Вы не используете протокол SLIP, можете убрать эту строку:

   set ipaddr getip

   goto Done

BailOut:

   ; Возникли какие-то проблемы
   ; Можете ввести имя и пароль вручную

   set screen keyboard on
   halt

Done:

endproc
